Top > 88VAユーザーズクラブ > Q&A集 > 81
#0081/9999 Q&A集
★タイトル (88VAUSER)  95/11/01  00:00  ( 59)
9.6    画面の一部を見せる「スポット処理」をしたいのですが。
★内容

 VAではグラフィックを重ねることができるので上にマスク用のグラフィック
を表示してやることでスポット処理を実現できるでしょう。BASICで行うの
にはリファレンスマニュアルのCOMPOSE コマンドのプログラム例を実行するとわ
かりやすいかと思います。

 NEC Personal Computer PC-88VA2/VA3 N88日本語BASIC V3
       REFERENCE MANUAL         Page 87より
========================================================================
100 'COMPOSE サンプル
110 SCREEN WIDTH 7,320,4,320,4
120 WIDTH 80,25:CONSOLE 0,22,1,1:CLS 3
130 COLOR 14
140 FOR I=3 TO 20
150   LOCATE 18,I:PRINT "888888888888888888888888888888888"
160 NEXT I
170 SPRITE SCREEN 1
180 DIM A%(513)
190 A%(0)=32*2:A%(1)=16*4
200 FOR I=2 TO 64*2*4+1
210   A%(I)=&HFFFF
220 NEXT
230 PUT PATTERN 1,A%,1,4
240 PALETTE 30,&HFFE0:PALETTE 31,-1
250 BUFFER=0
260 LINE (40,32)-(160,120),1,BF
270 LINE (40,128)-(160,300),1,BF
280 BUFFER=8
290 LINE (100,110)-(250,350),2,BF
300 LOCATE 0,0:COLOR 15
310 PRINT "0=テキスト 1=スプライト 2=グラフィック0(アオ) 3=グラフィック1(アカ)"
320 FOR P=1 TO 10
330   READ FST,SND,TRD,FTH
340   LOCATE 0,1:PRINT "現在の優先順位";FST;SND;TRD;FTH
350   COMPOSE FST,SND,TRD,FTH,7
360   GOSUB 450
370 NEXT P
380 PALETTE:PALETTE 31,&HFFFF
390 COMPOSE 1,0,2,3
400 PALETTE:PALETTE 31,&HFFFF
410 SPRITE SCREEN 1
420 BUFFER=0:CLS 3
430 BUFFER=8:CLS 3
440 END
450 '
460 TURN ON SPRITE
470 FOR I=650 TO 0 STEP -1
480   LOCATE SPRITE 1,I,89,1:FOR J=0 TO 11:NEXT J
490 NEXT I
500 FOR TT=0 TO 1000:NEXT
510 RETURN
520 DATA 1,0,2,3,1,0,3,2,1,2,0,3,1,2,3,0
530 DATA 2,1,0,3,2,1,3,0,2,3,1,0
540 DATA 3,1,0,2,3,1,2,0,3,2,1,0
========================================================================

                         <<< end of article >>>


Top > 88VAユーザーズクラブ > Q&A集 > 81